excel中如何利用公式求得某一列中包含某一字母、多个数字对应列的面积总和。

Question

A B C D E F G H
1 物料组 特殊工艺 单只面积 单元数 钻孔 成型 终检 包装
2
3
4 20 ABJ 0.108 120 1235 45
5 15 JF 0.158 48 220 312
6 10 BF 1.325 12 445
7 10 AJ 0.045 2 770
8 15 1.255 30 150 124
9 20 B 0.109 3 70
10 10 A 1.876 9 34
11 8 J 0.987 15 111 490

面积=E4*D4*C4

1、要求在E2单元格中求出E4~E11对应 B4~B11列特殊工艺中包含字母“B”对应值的面积总和。
2、要求在E3单元格中求出E4~E11对应 A4~A11列中物料组中包含数字“20”对应值的面积总和。
2、要求在E3单元格中求出E4~E11对应 A4~A11列中物料组中包含数字“20”对应值的面积总和。（只有一个物料组”20“对应的面积总和）

这点中，还会需求出在E3单元格中求出E4~E11对应 A4~A11列中物料组中包含多个物料组”15“”8“的面积总和。

Answer 1

E2公式：

=SUMPRODUCT(ISNUMBER(FIND("B",B4:B11))*C4:C11*D4:D11)

 

E3公式：

=SUMPRODUCT(ISNUMBER(FIND("20",A4:A11))*C4:C11*D4:D11)

 

补充一下：

如果还要算上E4:E11的。

E2公式：

=SUMPRODUCT(ISNUMBER(FIND("B",B4:B11))*C4:C11*D4:D11*E4:E11)

 

E3公式：

=SUMPRODUCT(ISNUMBER(FIND("20",A4:A11))*C4:C11*D4:D11*E4:E11)

追问

那如果我想求物料组”20“和15”和“8”三个一起对应的面积总和，如何设公式呢。

追答

把公式改为这样：
=SUMPRODUCT(ISNUMBER(FIND({"20","15","8"},A4:A11))*C4:C11*D4:D11*E4:E11)

Answer 2

E2
=SUMIF(B4:B11,"*B*",E4:E11)
E3
=SUMIF(A4:A11,20,E4:E11)

追问

E4:E11只是数值，从你的公式中并没有关联系到C D两列的数，是没有转换为面积呀。注：E4中数值的面积=E4*D4*C4

追答

E2
=SUMPRODUCT(ISNUMBER(FIND("B",B4:B11))*E4:E11*D4:D11*C4:C11)
E3
=SUMPRODUCT((A4:A11=10)*E4:E11*D4:D11*C4:C11)